Add sanitizer features to unix_cc_toolchain_config

Author: Oliver Lee

tests/sanitizers/BUILD.bazel

@@ -0,0 +1,64 @@
+load("@rules_cc//cc:defs.bzl", "cc_binary", "cc_library", "cc_test")
+
+cc_binary(
+    name = "asan_example",
+    srcs = ["asan_example.cpp"],
+    features = ["asan"],
+)
+
+cc_binary(
+    name = "tsan_example",
+    srcs = ["tsan_example.cpp"],
+    features = ["tsan"],
+)
+
+cc_binary(
+    name = "ubsan_example",
+    srcs = ["ubsan_example.cpp"],
+    features = ["ubsan"],
+)
+
+sh_test(
+    name = "asan_test",
+    srcs = ["sanitizer_test.sh"],
+    data = [
+        ":asan_example",
+    ],
+    env = {
+        "BINARY": "$(rootpath :asan_example)",
+    },
+    args = [
+        "'ERROR: AddressSanitizer: stack-use-after-scope'",
+    ],
+)
+
+sh_test(
+    name = "tsan_test",
+    srcs = ["sanitizer_test.sh"],
+    data = [
+        ":tsan_example",
+    ],
+    env = {
+        "BINARY": "$(rootpath :tsan_example)",
+    },
+    args = [
+        "'WARNING: ThreadSanitizer: data race (pid=.*)'",
+        "'Write of size .* at .* by thread T.*:'",
+        "'Previous write of size .* at .* by thread T.*:'",
+    ],
+)
+
+sh_test(
+    name = "ubsan_test",
+    srcs = ["sanitizer_test.sh"],
+    data = [
+        ":ubsan_example",
+    ],
+    env = {
+        "BINARY": "$(rootpath :ubsan_example)",
+    },
+    args = [
+        "'sanitizers/ubsan_example.cpp:3:11: runtime error: division by zero'",
+        "'SUMMARY: UndefinedBehaviorSanitizer: undefined-behavior sanitizers/ubsan_example.cpp:3:11 in'",
+    ],
+)

tests/sanitizers/asan_example.cpp

@@ -0,0 +1,10 @@
+#include <iostream>
+#include <string>
+
+auto main() -> int
+{
+    const auto f = [] () -> const auto& {
+        return std::string{"hello, world!"};
+    };
+    std::cout << f() << "\n";
+}

tests/sanitizers/sanitizer_test.sh

@@ -0,0 +1,8 @@
+#!/usr/bin/env bash
+set -eu
+
+output=$($BINARY 2>&1 || true)
+
+for arg in "$@"; do
+    echo $output | grep -q "$arg"
+done

tests/sanitizers/tsan_example.cpp

@@ -0,0 +1,14 @@
+#include <thread>
+
+auto main() -> int
+{
+  auto i = int{};
+  const auto inc = [&i] { ++i; };
+
+  auto t1 = std::thread{inc};
+  auto t2 = std::thread{inc};
+  t1.join();
+  t2.join();
+
+  return i;
+}

tests/sanitizers/ubsan_example.cpp

@@ -0,0 +1,4 @@
+auto main() -> int
+{
+  return 1/0;
+}

toolchain/unix_cc_toolchain_config.bzl

@@ -143,6 +143,36 @@ lto_index_actions = [
     ACTION_NAMES.lto_index_for_nodeps_dynamic_library,
 ]
 
+def _sanitizer_feature(name = "", specific_compile_flags = [], specific_link_flags = []):
+    return feature(
+        name = name,
+        flag_sets =[
+            flag_set(
+                actions = all_compile_actions,
+                flag_groups = [
+                    flag_group(flags = [
+                        "-O1",
+                        "-gline-tables-only",
+                        "-fno-omit-frame-pointer",
+                        "-fno-sanitize-recover=all",
+                    ] + specific_compile_flags),
+                ],
+                with_features = [
+                    with_feature_set(features = [name])
+                ],
+            ),
+            flag_set(
+                actions = all_link_actions,
+                flag_groups = [
+                    flag_group(flags = specific_link_flags),
+                ],
+                with_features = [
+                    with_feature_set(features = [name])
+                ],
+            ),
+        ],
+    )
+
 def _impl(ctx):
     tool_paths = [
         tool_path(name = name, path = path)
@@ -1215,6 +1245,37 @@ def _impl(ctx):
         enabled = True,
     )
 
+    asan_feature = _sanitizer_feature(
+        name = "asan",
+        specific_compile_flags = [
+            "-fsanitize=address",
+            "-fno-common",
+        ],
+        specific_link_flags = [
+            "-fsanitize=address",
+        ],
+    )
+
+    tsan_feature = _sanitizer_feature(
+        name = "tsan",
+        specific_compile_flags = [
+            "-fsanitize=thread",
+        ],
+        specific_link_flags = [
+            "-fsanitize=thread",
+        ],
+    )
+
+    ubsan_feature = _sanitizer_feature(
+        name = "ubsan",
+        specific_compile_flags = [
+            "-fsanitize=undefined",
+        ],
+        specific_link_flags = [
+            "-fsanitize=undefined",
+        ],
+    )
+
     is_linux = ctx.attr.target_libc != "macosx"
     libtool_feature = feature(
         name = "libtool",
@@ -1255,6 +1316,9 @@ def _impl(ctx):
             strip_debug_symbols_feature,
             coverage_feature,
             supports_pic_feature,
+            asan_feature,
+            tsan_feature,
+            ubsan_feature,
         ] + (
             [
                 supports_start_end_lib_feature,